Private Sub LoadSprite(FilePath As String, SpriteOffset As Long, PaletteOffset As Long, Height As Long, Width As Long)
    'Set the global image properties
    m_lngGraphicHeightBlocks = Height
    m_lngGraphicWidthBlocks = Width
    'Gets us a new file handle.
    iFreeFile = FreeFile
    'Current position in decoding
    Dim lngCurrentPosition As Long
    'Resizes the buffers for the required space.
    ReDim Buffer(0 To ((m_lngGraphicHeightBlocks * 8) * (m_lngGraphicWidthBlocks * 8)))
    ReDim EditBuffer(0 To ((m_lngGraphicHeightBlocks * 8) * (m_lngGraphicWidthBlocks * 8)))
    'Resize the Sprite View (Double-Size mode!)
    picViewSprite.Width = (m_lngGraphicWidthBlocks * 8) * 2
    picViewSprite.Height = (m_lngGraphicHeightBlocks * 8) * 2
    'Reset current tile
    m_lngCurrentTile = 0
    shpSelectedTile.Top = 0
    shpSelectedTile.Left = 0
    'Set offsets
    m_lngGraphicStartOffset = SpriteOffset
    'Opens the ROM
    Open FilePath For Binary As #iFreeFile
        'Goto the offset of the Palette
        Seek #iFreeFile, PaletteOffset
        'Load the Palette up
        Get #iFreeFile, , PaletteData
        'Goto offset of sprite
        Seek #iFreeFile, SpriteOffset
        'The Y-Line is the row of blocks we are reading
        For YLine = 0 To m_lngGraphicHeightBlocks - 1
            'The X-Line is the column of blocks we are reading
            For XLine = 0 To m_lngGraphicWidthBlocks - 1
                For Y = 0 To 7
                    'We are reading the data in chunks of DWORD's! HOW EFFECIENT OF ME!
                    'I MUST BE GAWD!
                    Get #iFreeFile, , Data1
                    Get #iFreeFile, , Data2
                    Get #iFreeFile, , Data3
                    Get #iFreeFile, , Data4
                    '4BPP graphics are 4-bits per pixel, so 4 bytes is 8 pixels or 1 row.
                    'they are in reverse order. XXXXRRRR
                    'RRRR = First Pixel
                    'XXXX = Second Pixel
                    'Below ...that could probely be shortend to a loop.
                    EditBuffer(lngCurrentPosition + 0) = (Data1 And &HF)  'High Nibble
                    EditBuffer(lngCurrentPosition + 1) = (Data1 \ 16)     'Low Nibble
                    EditBuffer(lngCurrentPosition + 2) = (Data2 And &HF)  'High Nibble
                    EditBuffer(lngCurrentPosition + 3) = (Data2 \ 16)     'Low Nibble
                    EditBuffer(lngCurrentPosition + 4) = (Data3 And &HF)  'High Nibble
                    EditBuffer(lngCurrentPosition + 5) = (Data3 \ 16)     'Low Nibble
                    EditBuffer(lngCurrentPosition + 6) = (Data4 And &HF)  'High Nibble
                    EditBuffer(lngCurrentPosition + 7) = (Data4 \ 16)     'Low Nibble
                    'Increase current position by 8
                    lngCurrentPosition = lngCurrentPosition + 8
                Next Y
            Next XLine
        Next YLine
    Close #iFreeFile
End Sub

Private Sub SaveSprite(FilePath As String, SpriteOffset As Long, Height As Long, Width As Long)
    'Current position in decoding
    Dim lngCurrentPosition As Long
    Dim bytTempBuffer() As Byte
    On Error GoTo ErrSaveSprite
    ReDim bytTempBuffer((UBound(EditBuffer) \ 2) - 1)
    'Make sure file is open
    If Len(m_strCurrentROM) <= 0 Or m_blnROMOpened = False Then Exit Sub
    'Gets us a new file handle.
    iFreeFile = FreeFile
    'Opens the ROM
    Open m_strCurrentROM For Binary As #iFreeFile
        'Goto offset of sprite
        Seek #iFreeFile, SpriteOffset
        For i = 0 To UBound(EditBuffer) - 1 Step 2
            bytTempBuffer(lngCurrentPosition) = EditBuffer(i) Or (EditBuffer(i + 1) * 16)
            lngCurrentPosition = lngCurrentPosition + 1
        Next i
        Put #iFreeFile, , bytTempBuffer
    Close #iFreeFile

    On Error GoTo 0
    Exit Sub

ErrSaveSprite:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure SaveSprite of frmOverworldEditor", vbCritical

    
End Sub